(*************************************************************************

 *

 *  OpenOffice.org - a multi-platform office productivity suite

 *

 *  $RCSfile: main.applescript,v $

 *

 *  $Revision: 1.7 $

 *

 *  last change: $Author: vg $ $Date: 2006/11/22 11:56:26 $

 *

 *  The Contents of this file are made available subject to

 *  the terms of GNU Lesser General Public License Version 2.1.

 *

 *		

 *    GNU Lesser General Public License Version 2.1

 *    =============================================

 *    Copyright 2005 by Sun Microsystems, Inc.

 *    901 San Antonio Road, Palo Alto, CA 94303, USA

 *

 *    This library is free software; you can redistribute it and/or

 *    modify it under the terms of the GNU Lesser General Public

 *    License version 2.1, as published by the Free Software Foundation.

 *

 *    This library is distributed in the hope that it will be useful,

 *    but WITHOUT ANY WARRANTY; without even the implied warranty of

 *    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

 *    Lesser General Public License for more details.

 *

 *    You should have received a copy of the GNU Lesser General Public

 *    License along with this library; if not, write to the Free Software

 *    Foundation, Inc., 59 Temple Place, Suite 330, Boston,

 *    MA  02111-1307  USA

 *

 *************************************************************************)

(*==== (global variables as get-functions) ====*)

on getOOInstallPath()

	-- return (((path to applications folder from system domain) as string) & "OpenOffice XXXOOO_VER_MAJORMINORXXX.app:" & "Contents:MacOS:")

	return (((path to me) as string) & "Contents:MacOS:")

end getOOInstallPath

on getOOResourcesPath()

	return (((path to me) as string) & "Contents:Resources:")

end getOOResourcesPath

on getOOProgramPath()

	return (getOOInstallPath() & "program:")

end getOOProgramPath

on getScriptPath()

	-- set this to absolute path when debugging

	return (((path to me) as string) & "Contents:Resources:Scripts:")

end getScriptPath

on getOOUserSettingsPath()

	return (((path to home folder) as string) & "Library:Application Support:OpenOffice.org:XXXOOO_VER_MAJORXXX:")

end getOOUserSettingsPath

on getOOUserFontPath()

	return (getOOUserSettingsPath() & "user:fonts:")

end getOOUserFontPath

on getUserLogsPath()

	return (((path to home folder) as string) & "Library:Logs:")

end getUserLogsPath

on shellTerminator()

	return (" &>/dev/null & echo $!") as string

end shellTerminator

--

-- the default handlers: run, open, idle, quit

--

on run

	if (preRun()) then

		logEvent("(Scripts/main) Running OpenOffice.org")

		openSoffice("-")

	end if

end run

on open (theFiles)

	if (preRun()) then

		openFiles(theFiles)

	end if

end open

on idle

	-- close icon only if ooo has terminated

	if (hasOOoQuit()) then

		tell me to quit

	end if

	-- check all x seconds if ok to quit

	return 3

end idle

on quit

	if (hasOOoQuit()) then

		continue quit

	end if

end quit

-------------------------------------------------------------

on preRun()

	-- Check for the required version of Mac OS X

	if (not atLeastOSXVersion(10, 3, 0)) then

		display dialog getMessage("ERROR_NEED_PANTHER")

		return false

	end if

	-- Check for that OOo can be found

	if (not isRealPath(getOOProgramPath())) then

		display dialog getMessage("ERROR_OOO_NOT_FOUND")

		return false

	end if

	-- Migrate the old user preference folder, if possible. (~/Library/Application Support/OpenOffice.org 2.0/)

	if (not isRealPath(getOOUserSettingsPath())) then

		set oldPrefsPath to (((path to home folder) as string) & "Library:Application Support:OpenOffice.org 2.0:")

		migrateUserPrefs(oldPrefsPath)

	end if

	-- Migrate the old user preference folder, if possible. (~/.openoffice.org2/)

	if (not isRealPath(getOOUserSettingsPath())) then

		set oldPrefsPath to (((path to home folder) as string) & ".openoffice.org2:")

		migrateUserPrefs(oldPrefsPath)

	end if

	if (not isRealPath(getOOUserFontPath())) then

		set createUserFont to "mkdir -p " & (quoted form of POSIX path of getOOUserFontPath()) & "; "

		do shell script createUserFont

	end if

	-- If no crash occured before, ~/Library/Logs does not exist, and OpenOffice.org cannot be started

	if (not isRealPath(getUserLogsPath())) then

		set createUserLogsPath to "mkdir -p " & (quoted form of POSIX path of getUserLogsPath()) & "; "

		do shell script createUserLogsPath

	end if

	-- Checks are ok, now do the PostInstall stuff (e.g. fondu)

	-- load helper library

	set postinstall to load script alias Â

		(getScriptPath() & "PostInstall.scpt")

	-- execute the postinstall script

	run of postinstall

	return true

end preRun

on hasOOoQuit()

	if (isRealPath(getOOProgramPath())) then

		-- set the location of soffice binary

		set soffice to (quoted form of (POSIX path of getOOProgramPath() & "soffice"))

		set isRunning to do shell script "_FOUND_=`ps -wx -o command | grep " & soffice & " | grep -v grep`; echo $_FOUND_"

		if isRunning ­ "" then

			return false

		else

			return true

		end if

	else

		return true

	end if

end hasOOoQuit

on openSoffice(aFile)

	set theDisplay to startXServer()

	if (theDisplay is equal to "error") then

		return

	end if

	set theEnv to "DISPLAY=" & theDisplay & " ; export DISPLAY; "

	set theCmd to "sh " & (quoted form of (POSIX path of getOOProgramPath() & "soffice")) & " "

	do shell script theEnv & theCmd & aFile & shellTerminator()

	-- logEvent("open CMD: " & theEnv & theCmd & aFile)

end openSoffice

-- helper function to start X11 server

on startXServer()

	-- get X settings

	set XSettingsList to findXServer()

	set whichserver to item 1 of XSettingsList

	set Xserverloc to item 2 of XSettingsList

	-- debug:

	-- logEvent("(scripts/main) X settings: " & whichserver & "--" & POSIX path of Xserverloc)

	-- set whichserver to "NOXSERVER"

	-- if nothing really was found, display an error message.

	if (whichserver is equal to "NOXSERVER") then

		display dialog getMessage("ERROR_NEED_X11")

		return "error"

	end if

	set now_running to ""

	set now_running to do shell script "INX=`ps -wcx | grep  " & quoted form of (whichserver & "$") & "`; echo $INX"

	if whichserver = "NOXSERVER" then

		-- display dialog "No XServer Found"

		set now_running to "Skip"

	end if

	if now_running = "" then

		if whichserver = "X11" then

			set x11cmd to quoted form of (Xserverloc & "/Contents/MacOS/X11") & shellTerminator()

			do shell script x11cmd

			-- save process id

			set x11pid to the result

			-- wait until the window manager is started which is the second child process of x11

			set numchildrencmd to "ps -x -o ppid | grep " & x11pid & " | wc -l"

			set numchildren to 0

			set d to current date

			set t1 to time of d

			repeat while numchildren ­ 2

				set d to current date

				set t2 to time of d

				-- give up after 30 seconds

				if t2 - t1 > 30 then

					display dialog "Command timed out"

					exit repeat

				end if

				set result to do shell script numchildrencmd

				set numchildren to result as integer

			end repeat

		else -- startup XDarwin

			do shell script "open " & quoted form of Xserverloc & shellTerminator()

			do shell script "sleep 4"

		end if

	end if

	if whichserver is equal to "X11" then

		-- the DISPLAY variable is different for every user currently logged in

		-- X11 passes the DISPLAY as the last command line parameter to its child process

		-- we can use ps to read the command line and parse the trailing :0, :1, or whatever

		set xdisplay to do shell script "ps -wx -o command | grep X11.app | grep \":.$\" | sed \"s/^.*:/:/g\""

		--display dialog xdisplay

		return xdisplay

	else

		-- TODO: find out how XDarwin does it

		return ":0"

	end if

end startXServer

on openFiles(fileList)

	if (count of fileList) > 0 then

		repeat with i from 1 to the count of fileList

			set theDocument to (item i of fileList)

			set theFilePath to (quoted form of POSIX path of theDocument)

			set theFileInfo to (info for theDocument)

			openSoffice(theFilePath)

			logEvent("(Scripts/main) Open file: " & theFilePath)

		end repeat

	end if

end openFiles

(* ===== (Helper functions) ======= *)

-- get a localized string

on getMessage(aKey)

	try

		if (aKey is equal to "YES_KEY") then

			return "Yes"

		end if

		if (aKey is equal to "NO_KEY") then

			return "No"

		end if

		if (aKey is equal to "ERROR_OOO_NOT_FOUND") then

			return "OpenOffice.org was not found on your system. Please (re-)install OpenOffice.org first."

		end if

		if (aKey is equal to "ERROR_NEED_PANTHER") then

			return "This build of OpenOffice.org cannot be run on this system, OpenOffice.org requires MacOSX 10.3 (Panther) or newer system"

		end if

		if (aKey is equal to "ERROR_NEED_X11") then

			return "OpenOffice.org cannot be started, because X11 is not installed. Please install Apple X11 first."

		end if

	end try

end getMessage

-- function for logging script messages

on logEvent(themessage)

	set theLine to (do shell script Â

		"date  +'%Y-%m-%d %H:%M:%S'" as string) Â

		& " " & themessage

	do shell script "echo " & quoted form of theLine & Â

		" >> ~/Library/Logs/OpenOfficeXXXOOO_VER_MAJORXXX.log"

end logEvent

-- function for checking if a path exists

on isRealPath(aPath)

	try

		alias aPath

		return true

	on error

		-- error number -43 from aPath

		-- display dialog "NotRP -- " & aPath

		return false

	end try

end isRealPath

-- try to find X11 server on the Mac OS X system

-- return value: the found server or "NOXSERVER"

on findXServer()

	-- First try standard X11 location, then try standard XDarwin location

	set whichserver to "NOXSERVER"

	--Utilities folder of system

	set Xserverloc to ((path to utilities folder from system domain) as string) & "X11.app:"

	--display dialog " Xserverloc" & Xserverloc

	if (isRealPath(Xserverloc)) then

		set whichserver to "X11"

		set Xserverloc to (POSIX path of Xserverloc)

	else

		--Applications folder of system

		set Xserverloc to ((path to applications folder from system domain) as string) & "XDarwin.app:"

		if (isRealPath(Xserverloc)) then

			set whichserver to "XDarwin"

			set Xserverloc to (POSIX path of Xserverloc)

		end if

	end if

	-- if nothing found yet try using locate, first with X11.app and then with XDarwin.app

	if (whichserver is equal to "NOXSERVER") then

		set Xserverloc to do shell script "locate X11.app/Contents/MacOS/X11 | sed -e 's-/Contents/MacOS/X11--g'"

		if Xserverloc ­ "" then

			set whichserver to "X11"

		end if

	end if

	if (whichserver is equal to "NOXSERVER") then

		set Xserverloc to do shell script "locate XDarwin.app/Contents/MacOS/XDarwin | sed -e 's-/Contents/MacOS/XDarwin--g'"

		if Xserverloc ­ "" then

			set whichserver to "XDarwin"

		end if

	end if

	return {whichserver, Xserverloc}

end findXServer

-- Test for a minimum version of Mac OS X

on atLeastOSXVersion(verMajor, verMinor, verStep)

	-- The StandardAdditions's 'system attribute' used to be the Finder's 'computer' command.

	tell application "Finder" to set sysv to (system attribute "sysv")

	-- Generate sysv-compatible number from given version

	set reqVer to ((verMajor div 10) * 4096 + (verMajor mod 10) * 256 + verMinor * 16 + verStep)

	-- DEBUGGING:	

	-- display dialog ("RV:" & reqVer & " < " & sysv as string)

	-- set major to ((sysv div 4096) * 10 + (sysv mod 4096 div 256))

	-- set minor to (sysv mod 256 div 16)

	-- set step to (sysv mod 16)

	-- display dialog ("Your Mac OS X version: " & major & "." & minor & "." & step)

	if (reqVer > sysv) then

		return false

	else

		return true

	end if

end atLeastOSXVersion

-- Migrate older user pref dir paths, if possible

on migrateUserPrefs(oldpath)

	-- if the old prefs can be found...

	if (isRealPath(oldpath)) then

		set newPathParent to (((path to home folder) as string) & "Library:Application Support:OpenOffice.org:")

		-- check if the new base user prefs directory exists, and create the folder if it doesn't

		if (not isRealPath(newPathParent)) then

			set createUserPrefsBasePath to "mkdir -p " & (quoted form of POSIX path of newPathParent) & "; "

			do shell script createUserPrefsBasePath

		end if

		-- migrate the old prefs to the new folder

		set newPath to (quoted form of POSIX path of getOOUserSettingsPath())

		set migratePrefs to "mv " & (quoted form of POSIX path of oldpath) & " " & newPath & "; "

		do shell script migratePrefs

	end if

end migrateUserPrefs

<?xml version="1.0" encoding="UTF-8"?>

<!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">

<plist version="1.0">

<dict>

	<key>IFPkgDescriptionDescription</key>

	<string>OpenOffice.org for Mac OS X.

Mac OS X 10.4 or later is required.  </string>

	<key>IFPkgDescriptionTitle</key>

	<string>OpenOffice.org</string>

</dict>

</plist>

<?xml version="1.0" encoding="UTF-8"?>

<!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">

<plist version="1.0">

<dict>

	<key>CFBundleGetInfoString</key>

	<string>XXXOOO_VER_MAJORMINORXXX, OpenOffice.org</string>

	<key>CFBundleIdentifier</key>

	<string>org.openoffice.office</string>

	<key>CFBundleShortVersionString</key>

	<string>XXXOOO_VER_MAJORMINORXXX</string>

	<key>IFMajorVersion</key>

	<integer>1</integer>

	<key>IFMinorVersion</key>

	<integer>0</integer>

	<key>IFPkgFlagAllowBackRev</key>

	<false/>

	<key>IFPkgFlagAuthorizationAction</key>

	<string>AdminAuthorization</string>

	<key>IFPkgFlagBackgroundAlignment</key>

	<string>topleft</string>

	<key>IFPkgFlagBackgroundScaling</key>

	<string>none</string>

	<key>IFPkgFlagDefaultLocation</key>

	<string>/Applications</string>

	<key>IFPkgFlagFollowLinks</key>

	<true/>

	<key>IFPkgFlagInstallFat</key>

	<false/>

	<key>IFPkgFlagInstalledSize</key>

	<integer>300</integer>

	<key>IFPkgFlagIsRequired</key>

	<false/>

	<key>IFPkgFlagOverwritePermissions</key>

	<false/>

	<key>IFPkgFlagRelocatable</key>

	<false/>

	<key>IFPkgFlagRestartAction</key>

	<string>NoRestart</string>

	<key>IFPkgFlagRootVolumeOnly</key>

	<true/>

	<key>IFPkgFlagUpdateInstalledLanguages</key>

	<false/>

	<key>IFPkgFormatVersion</key>

	<real>0.10000000149011612</real>

</dict>

</plist>

(*************************************************************************

 *

 *  OpenOffice.org - a multi-platform office productivity suite

 *

 *  $RCSfile: PostInstall.applescript,v $

 *

 *  $Revision: 1.4 $

 *

 *  last change: $Author: vg $ $Date: 2006/11/22 11:56:14 $

 *

 *  The Contents of this file are made available subject to

 *  the terms of GNU Lesser General Public License Version 2.1.

 *

 *		

 *    GNU Lesser General Public License Version 2.1

 *    =============================================

 *    Copyright 2005 by Sun Microsystems, Inc.

 *    901 San Antonio Road, Palo Alto, CA 94303, USA

 *

 *    This library is free software; you can redistribute it and/or

 *    modify it under the terms of the GNU Lesser General Public

 *    License version 2.1, as published by the Free Software Foundation.

 *

 *    This library is distributed in the hope that it will be useful,

 *    but WITHOUT ANY WARRANTY; without even the implied warranty of

 *    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

 *    Lesser General Public License for more details.

 *

 *    You should have received a copy of the GNU Lesser General Public

 *    License along with this library; if not, write to the Free Software

 *    Foundation, Inc., 59 Temple Place, Suite 330, Boston,

 *    MA  02111-1307  USA

 *

 *************************************************************************)

-- This is the PostInstall -script for .pkg installation

-- 

-- Currently this script does the following things:

--   1) Uses fondu to extract and convert .dfont -fonts from Mac OS X system to .ttf -fonts for OpenOffice.org

(*==== (global variables as get-functions) ====*)

on getOOInstallPath()

	return (((path to applications folder from system domain) as string) & "OpenOffice XXXOOO_VER_MAJORMINORXXX.app:" & "Contents:MacOS:")

	-- return (((path to me) as string) & "Contents:MacOS:")

end getOOInstallPath

on getOOProgramPath()

	return (getOOInstallPath() & "program:")

end getOOProgramPath

-- OSXSystemFontPathList : {"/System/Library/Fonts/", "/Library/Fonts/"}

-- OSXUserFontPathList : {"~/Library/Fonts/"}

on getOSXSystemFontPathList()

	return {(path to fonts folder from system domain) as string, Â

		(path to fonts folder from local domain) as string}

end getOSXSystemFontPathList

on getOSXUserFontPathList()

	return {(path to fonts folder from user domain) as string}

end getOSXUserFontPathList

on getOOSystemFontPath()

	return (getOOInstallPath() & "share:fonts:truetype:")

end getOOSystemFontPath

on getOOUserSettingsPath()

	return (((path to home folder) as string) & "Library:Application Support:OpenOffice.org:XXXOOO_VER_MAJORXXX:")

end getOOUserSettingsPath

on getOOUserFontPath()

	return (getOOUserSettingsPath() & "user:fonts:")

end getOOUserFontPath

on getOOCookieSystemFondu()

	-- nosystemfondu : file does exist if user does not want to use fondu for system fonts

	return "no_system_fondu"

end getOOCookieSystemFondu

on getOOCookieSystemFonduDone()

	-- systemfondudone : file does exist if native fonts already extracted from system fonts

	return "system_fondu_done"

end getOOCookieSystemFonduDone

on getOOCookieUserFondu()

	-- nouserfondu : file does exist if user does not want to use fondu for user fonts

	return "no_user_fondu"

end getOOCookieUserFondu

on getOOCookieUserFonduDone()

	-- userfondudone : file does exist if native fonts already extracted from user fonts

	return "user_fondu_done"

end getOOCookieUserFonduDone

--

-- the default handler: run

--

on run

	-- Check for that OOo can be found

	if (not isRealPath(getOOProgramPath())) then

		logEvent("(scripts/PostInstall) ERROR: could not find OOo installation from " & POSIX path of getOOProgramPath())

		return

	end if

	-- Migrate the old user preference folder, if possible. (~/Library/Application Support/OpenOffice.org 2.0/)

	if (not isRealPath(getOOUserSettingsPath())) then

		set oldPrefsPath to (((path to home folder) as string) & "Library:Application Support:OpenOffice.org 2.0:")

		migrateUserPrefs(oldPrefsPath)

	end if

	-- Migrate the old user preference folder, if possible. (~/.openoffice.org2/)

	if (not isRealPath(getOOUserSettingsPath())) then

		set oldPrefsPath to (((path to home folder) as string) & ".openoffice.org2:")

		migrateUserPrefs(oldPrefsPath)

	end if

	if (not isRealPath(getOOUserFontPath())) then

		set createUserFont to "mkdir -p " & (quoted form of POSIX path of getOOUserFontPath()) & "; "

		do shell script createUserFont

	end if

	-- If no crash occured before, ~/Library/Logs does not exist, and OpenOffice.org cannot be started

	if (not isRealPath(getUserLogsPath())) then

		set createUserLogsPath to "mkdir -p " & (quoted form of POSIX path of getUserLogsPath()) & "; "

		do shell script createUserLogsPath

	end if

	-- checks are ok, now we can start doing the real stuff

	firstLaunch()

	runSystemFondu()

	runUserFondu()

	return

end run

-------------------------------------------------------------

on runSystemFondu()

	-- check if user does not want font conversion 

	if (isRealPath(getOOSystemFontPath() & getOOCookieSystemFondu())) then

		return

	end if

	-- check if font conversion was already run

	if (isRealPath(getOOSystemFontPath() & getOOCookieSystemFonduDone())) then

		return

	end if

	logEvent("(scripts/PostInstall) Extracting system fonts...")

	-- else try to create footprint

	if (setCookie(getOOSystemFontPath(), getOOCookieSystemFonduDone())) then

		-- call fondu for each font (i.e. without wildcard), so if it crashes only one font is missing

		fonduConvertFonts(getOOSystemFontPath(), getOSXSystemFontPathList())

	end if

	logEvent("(scripts/PostInstall) Extracting system fonts completed.")

end runSystemFondu

on runUserFondu()

	-- check if user does not want font conversion 

	if (isRealPath(getOOUserFontPath() & getOOCookieUserFondu())) then

		return

	end if

	-- check if font conversion was already run

	if (isRealPath(getOOUserFontPath() & getOOCookieUserFonduDone())) then

		return

	end if

	logEvent("(scripts/PostInstall) Extracting user fonts...")

	-- try to create footprint

	if (setCookie(getOOUserFontPath(), getOOCookieUserFonduDone())) then

		-- call fondu for each font (i.e. without wildcard), so if it crashes only one font is missing

		fonduConvertFonts(getOOUserFontPath(), getOSXUserFontPathList())

	end if

	logEvent("(scripts/PostInstall) Extracting user fonts completed.")

end runUserFondu

on firstLaunch()

	-- continue only if OOSysFontdir exists	

	if (not isRealPath(getOOSystemFontPath())) then

		logEvent("(scripts/PostInstall) ERROR: could not find System font folder from " & POSIX path of getOOSystemFontPath())

		return

	end if

	if (setCookie(getOOSystemFontPath(), getOOCookieSystemFondu() & ".in_progress")) then

		-- Has user already decided that he does not want to extract system fonts ?

		if (not isRealPath(getOOSystemFontPath() & getOOCookieSystemFondu())) then

			-- Are system fonts already extracted ?

			if (not isRealPath(getOOSystemFontPath() & getOOCookieSystemFonduDone())) then

				-- ask if the user wants to use fondu to extract system fonts

				set yesKey to getMessage("YES_KEY")

				set noKey to getMessage("NO_KEY")

				display dialog getMessage("OOO_EXTRACT_NATIVE_SYSFONTS") buttons {noKey, yesKey} default button yesKey

				set theResult to the button returned of the result

				if theResult is noKey then

					-- not use fondu for system fonts extraction !

					setCookie(getOOSystemFontPath(), getOOCookieSystemFondu())

					logEvent("(scripts/PostInstall) Setting: no system fonts")

				end if

			end if

		end if

	end if

	-- continue only if OOUserFontdir exists	

	if (not isRealPath(getOOUserFontPath())) then

		logEvent("(scripts/PostInstall) ERROR: could not find User font folder from " & POSIX path of getOOUserFontPath())

		return

	end if

	-- Has user already decided that he does not want to extract user fonts ?

	if (not isRealPath(getOOUserFontPath() & getOOCookieUserFondu())) then

		-- Are system fonts already extracted ?

		if (not isRealPath(getOOUserFontPath() & getOOCookieUserFonduDone())) then

			-- ask if the user wants to use fondu to extract user fonts

			set yesKey to getMessage("YES_KEY")

			set noKey to getMessage("NO_KEY")

			display dialog getMessage("OOO_EXTRACT_NATIVE_USERFONTS") buttons {noKey, yesKey} default button yesKey

			set theResult to the button returned of the result

			if theResult is noKey then

				-- not use fondu for user fonts extraction !

				setCookie(getOOUserFontPath(), getOOCookieUserFondu())

				logEvent("(scripts/PostInstall) Setting: no user fonts")

			end if

		end if

	end if

end firstLaunch

on fonduConvertFonts(targetPath, sourcePathList)

	-- define the location of fondu

	set fondu to quoted form of (POSIX path of getOOProgramPath() & "fondu")

	-- first go to the target directory

	set fonduCmd to "cd " & (quoted form of POSIX path of targetPath) & "; "

	repeat with q from 1 to number of items in sourcePathList

		set aPath to POSIX path of (item q of sourcePathList)

		set fonduCmd to fonduCmd & "for i in " & aPath & "*; do " & fondu & " -force \"$i\" >> /dev/null 2>&1; done; "

	end repeat

	try

		-- ignore errors

		-- with admin privileges does not work well on panther

		do shell script "sh -c " & quoted form of fonduCmd

	end try

	logEvent("fonduCMD: " & fonduCmd)

end fonduConvertFonts

(* ===== (Helper functions) ======= *)

-- set a cookiefile. The content is empty.

on setCookie(aPath, cookieFile)

	try

		if (isRealPath(aPath)) then

			set newFile to (aPath & cookieFile)

			open for access file newFile

			close access file newFile

			return true

		else

			return false

		end if

	on error

		return false

	end try

end setCookie

-- get a localized string

on getMessage(aKey)

	try

		if (aKey is equal to "YES_KEY") then

			return "Yes"

		end if

		if (aKey is equal to "NO_KEY") then

			return "No"

		end if

		if (aKey is equal to "OOO_EXTRACT_NATIVE_SYSFONTS") then

			return "Do you want OpenOffice.org to use the Apple system fonts?"

		end if

		if (aKey is equal to "OOO_EXTRACT_NATIVE_USERFONTS") then

			return "Do you want OpenOffice.org to use the fonts you have installed on this system?"

		end if

	end try

end getMessage

-- function for checking if a path exists

on isRealPath(aPath)

	try

		alias aPath

		return true

	on error

		-- error number -43 from aPath

		-- display dialog "NotRP -- " & aPath

		return false

	end try

end isRealPath

-- function for logging script messages

on logEvent(themessage)

	set theLine to (do shell script Â

		"date  +'%Y-%m-%d %H:%M:%S'" as string) Â

		& " " & themessage

	do shell script "echo " & quoted form of theLine & Â

		" >> ~/Library/Logs/OpenOfficeXXXOOO_VER_MAJORXXX.log"

end logEvent

#!/bin/csh

#

# run the PostInstall.applescript

osascript PostInstall.scpt

exit 0

#!/bin/sh

 ########################################################################

 #

 #  OpenOffice.org - a multi-platform office productivity suite

 #

 #  $RCSfile: create_pkg.sh,v $

 #

 #  $Revision: 1.1 $

 #

 #  last change: $Author: mox $ $Date: 2006/12/07 12:23:29 $

 #

 #  The Contents of this file are made available subject to

 #  the terms of GNU Lesser General Public License Version 2.1.

 #

 #

 #    GNU Lesser General Public License Version 2.1

 #    =============================================

 #    Copyright 2005 by Sun Microsystems, Inc.

 #    901 San Antonio Road, Palo Alto, CA 94303, USA

 #

 #    This library is free software; you can redistribute it and/or

 #    modify it under the terms of the GNU Lesser General Public

 #    License version 2.1, as published by the Free Software Foundation.

 #

 #    This library is distributed in the hope that it will be useful,

 #    but WITHOUT ANY WARRANTY; without even the implied warranty of

 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

 #    Lesser General Public License for more details.

 #

 #    You should have received a copy of the GNU Lesser General Public

 #    License along with this library; if not, write to the Free Software

 #    Foundation, Inc., 59 Temple Place, Suite 330, Boston,

 #    MA  02111-1307  USA

 #

 #######################################################################

# 

# create_pkg.sh - create pkg-installer for OpenOffice.org Spotlight Plugin

#

# Note: the final installation path is formed by combining the

# IFPkgFlagDefaultLocation -key in Info.plist with the contents of the $ROOTPATH

#

# Currently: "/Applications/OpenOffice.org <version>.app"

PACKAGEMAKER=/Developer/Applications/Utilities/PackageMaker.app/Contents/MacOS/PackageMaker

OOOVER="XXXOOO_VER_MAJORMINORXXX"

DESTPATH="../OpenOffice.org ${OOOVER}.pkg"

ROOTPATH=../application

RESOURCES=./Install_Resources

# XXX HACK

if [ -d "../OpenOffice.org.app" ]; then

   mv "../OpenOffice.org.app" "${ROOTPATH}/OpenOffice.org ${OOOVER}.app"

fi

if [ ! -d "${ROOTPATH}/OpenOffice.org ${OOOVER}.app" ]; then

    echo "create_pkg.sh ERROR: Cannot find the OpenOffice.org application"

    exit

fi

if [ -d "$DESTPATH" ]; then

    rm -rf "$DESTPATH"

fi

"${PACKAGEMAKER}" -build -p "$DESTPATH" -f "$ROOTPATH" -ds -v -r "$RESOURCES" -d Description.plist -i Info.plist

# ----  .app building ----

# --- Installer ---

$(INSTALLER).done : $(INSTRESOURCES).done $(installerfiles)

	touch "$@"

# create installer folder and copy all resources

$(INSTRESOURCES).done : 

	mkdir -p "$(INSTALLER)"

	test ! -d "$(INSTRESOURCES)" || rm -r "$(INSTRESOURCES)"

	cp -r installer_openoffice/Install_Resources "$(INSTALLER)$/"

	make_versioned.sh "$(INSTRESOURCES)$/PostInstall.applescript.template" "$(INSTRESOURCES)$/PostInstall.applescript"

	rm "$(INSTRESOURCES)$/PostInstall.applescript.template"

	cp "$(SOLVERPATH)$/bin$/osl$/LICENSE_en-US" "$(INSTRESOURCES)$/License.txt"

	cp "$(SOLVERPATH)$/bin$/osl$/README_en-US.html" "$(INSTRESOURCES)$/Welcome.html"

	touch "$@"

# all .plist files are just versioned and copied into the bundle	

$(INSTALLER)$/%.plist : installer_openoffice/%.plist

	make_versioned.sh "$<" "$@"

# all shell scripts are just copied

$(INSTALLER)$/%.sh : installer_openoffice/%.sh

	make_versioned.sh "$<" "$@"